Содержимое

# Функция СТИЛЬ

Применяет стиль к ячейке, содержащей формулу. После заданного количества времени может быть применён другой стиль.

Эта функция всегда возвращает значение 0, что позволяет использовать её, добавляя функцию СТИЛЬ в другую функцию в той же ячейке без изменения её значения.

Не следует использовать функцию СТИЛЬ без веских на то оснований, так как она предназначена прежде всего для использования в асинхронных функциях Add-In для визуального оповещения о доступности результата. Практически во всех остальных случаях лучше использовать условное форматирование.

### Синтаксис

СТИЛЬ("Стиль" [; Время [; "Стиль 2"]])

Стиль: имя стиля ячейки, применяемого к данной ячейке. Имена стилей регистронезависимы и должны вводиться в кавычках.

Время: необязательный диапазон времени в секундах. По истечении этого времени, применяется стиль Стиль 2. Оставьте этот параметр пустым, если в изменении стиля нет необходимости.

Стиль 2 необязательное имя стиля ячейки, назначаемое ячейке по истечении времени, указанного в параметре Время. При отсутствии данного параметра применяется стиль ячейки «По умолчанию».

В функциях LibreOffice Calc параметры, отмеченные, как "необязательные" могут быть пропущены, только если нет параметров, идущих после. Например, в функции с четырьмя параметрами, в которой последние два параметра "необязательные", вы можете пропустить 4-й параметр или 3-й и 4-й, но нельзя пропустить только 3-й параметр.

### Примеры

=10+СТИЛЬ("Good",60,"Neutral")

Вводит в ячейку значение 10 и применяет стиль под названием «Good». По истечении 60 секунд, применяется стиль «Neutral».

=A1*A2+СТИЛЬ(ЕСЛИ(ТЕКУЩ()<100,"Bad","Good"))

Вводит результат умножения значений в ячейках A1 и A2, и применяет стиль "Bad", если результат окажется меньше 100, в противном случае применяется стиль «Good». Здесь функция ТЕКУЩ() используется для получения текущего значения вычисления функции в ячейке.

="Total"&T(СТИЛЬ("Result"))

Вводит текст «Total» в ячейку и применяет стиль "Result". Обратите внимание, что в данном примере работа выполняется с текстовыми значениями, поскольку вывод функции СТИЛЬ необходимо присоединять к тексту с помощью оператора &. Функция Т() используется для предотвращения присоединения числа «0» к итоговому тексту.

#### Техническая информация

This function is not part of the Open Document Format for Office Applications (OpenDocument) Version 1.3. Part 4: Recalculated Formula (OpenFormula) Format standard. The name space is

ORG.OPENOFFICE.STYLE

См. также

Страница wiki функции СТИЛЬ.

Функции электронных таблиц

Назначение формата с помощью формулы

функция ТЕКУЩ

функция Т