Inhoud

# Werkbladfuncties

In deze sectie staan beschrijvingen van de Werkblad-functies met voorbeelden.

Om toegang te krijgen tot deze functie..

Invoegen - Functie - Categorie Werkblad

## TYPE.FOUT-functie

Geeft een getal dat een bepaald type fout aanduidt of de foutwaarde #N/A, als er geen fout is.

## OPMAAKPROFIEL

Past een stijl toe op de cel die de formule bevat.

## ADRES

Geeft een celadres (verwijzing) als tekst volgens de gespecificeerde rij- en kolomnummers. U kunt bepalen of het adres geïnterpreteerd wordt als een absoluut adres (bijvoorbeeld $A$1), een relatief adres (zoals A1) of in een gemengde vorm (A$1 of $A1). U kunt ook de naam van het blad specificeren.

Voor interoperabiliteit ondersteunen de functies ADRES en INDIRECT een optionele parameter om te specificeren of de adresnotatie R1C1 in plaats van de gebruikelijke notatie A1 moet worden gebruikt.

In ADRES wordt de parameter ingevoegd als de vierde parameter, waarbij de optionele parameter voor de bladnaam wordt verschoven naar de vijfde positie.

In INDIRECT wordt de parameter toegevoegd als de tweede parameter.

In beide functies wordt, als de instructie wordt ingevoegd met de waarde 0, de notatie R1C1 gebruikt. Als de instructie niet wordt opgegeven of een andere waarde dan 0 heeft, dan wordt de notatie A1 gebruikt.

In de notatie R1C1 geeft ADRES adressen als tekenreeksen terug met behulp van het uitroepteken '!' als het scheidingsteken voor de bladnaam en INDIRECT verwacht het uitroepteken als scheidingsteken voor de bladnaam. Beide functies gebruiken nog steeds de punt '.' als scheidingsteken voor de bladnaam met de notatie A1.

Bij het openen van documenten in de indeling ODF 1.0/1.1 zullen de ADRES-functies die een bladnaam als vierde parameter weergeven die bladnaam opschuiven om de vijfde parameter te worden. Een nieuwe vierde parameter met de waarde 1 zal worden ingevoegd.

Als ADRES-functies een vierde parameter hebben, zal die parameter worden verwijderd bij het opslaan in de indeling ODF 1.0/1.1.

Sla een werkblad niet op in de oude indeling ODF 1.0/1.1 als de nieuwe vierde parameter van de functie ADRES werd gebruikt met een waarde van 0.

De functie INDIRECT wordt opgeslagen zonder conversie naar de indeling ODF 1.0/1.1. Indien de tweede parameter aanwezig was, zal een oudere versie van Calc een fout voor die functie teruggeven.

#### Syntaxis

ADRES(Rij; Kolom ; ABS (optioneel); A1 (optioneel); Blad (optioneel))

Rij vertegenwoordigt het rijnummer voor de celverwijzingen

Kolom vertegenwoordigt het getal van de kolom voor de celverwijzing (het getal, niet de letter)

Abs bepaalt het type van de verwijzing:

1: absoluut ($A$1)

2: type rijverwijzing is absoluut; kolomverwijzing is relatief (A$1)

3: rij (relatief); kolom (absoluut) ($A1)

4: relatief (A1)

A1 (optioneel) - indien ingesteld op 0 wordt de notatie R1C1 gebruikt. Als de parameter niet wordt opgegeven of een andere waarde dan 0 heeft, dan wordt de notatie A1 gebruikt.

Blad vertegenwoordigt de naam van het werkblad. Het moet tussen dubbele aanhalingstekens geplaatst worden.

### Voorbeeld:

=ADRES(1;1;2;;"Blad2") geeft het volgende terug: Blad2.A$1

Als bovenstaande formule in cel B2 staat en als de cel A1 in blad 2 de waarde -6 bevat, kunt u indirect verwijzen naar de cel, waarnaar verwezen wordt met een functie in B2, door =ABS(INDIRECT(B2)) in te voeren. Het resultaat is de absolute waarde van de celverwijzing die is gespecificeerd in B2, wat in dit geval 6 is.

## BEREIKEN

Geeft het aantal afzonderlijke bereiken dat tot een meervoudig bereik behoort. Een bereik kan uit aaneengesloten cellen of één cel bestaan.

De functie verwacht één enkel argument. Indien u meerdere bereiken opgeeft, moet u ze omsluiten door aanvullende haakjes. Meerdere bereiken kunnen worden ingevoerd met behulp van de puntkomma (;) als scheidingsteken, maar dit wordt automatisch geconverteerd naar de operator tilde (~). De tilde wordt gebruikt om bereiken samen te voegen.

#### Syntaxis

BEREIKEN(Verwijzing)

'Verwijzing' staat voor de verwijzing naar een cel of celbereik.

#### Voorbeeld

=BEREIKEN((A1:B3;F2;G1)) geeft 3 terug, omdat het een verwijzing is naar drie cellen en/of gebieden. Na de invoer wordt dit geconverteerd naar =BEREIKEN((A1:B3~F2~G1)).

=BEREIKEN(Alle) geeft 1 terug als u een gebied genaamd Alle heeft gedefinieerd onder Gegevens - Bereik definiëren.

## BLAD

Geeft het bladnummer van een verwijzing of een tekenreeks die een bladnaam vertegenwoordigt. Als u geen parameters invoert, is het resultaat het bladnummer van het werkblad met de formule.

#### Syntaxis

BLAD([Verwijzing])

Verwijzing is optioneel en is de verwijzing naar een cel, een gebied, of de tekenreeks voor een bladnaam.

#### Voorbeeld

=BLAD(Blad2.A1) geeft 2 terug als Blad2 het tweede blad in het werkbladdocument is.

=BLAD("Blad3") geeft 3 terug als Blad3 het derde blad in het werkbladdocument is.

## BLADEN

Bepaalt het aantal bladen in een verwijzing. Als u geen parameters invoert, is het resultaat het aantal bladen in het huidige document.

#### Syntaxis

BLADEN([Verwijzing])

Verwijzing is de verwijzing naar een blad of een gebied. Deze parameter is optioneel.

#### Voorbeeld

=BLADEN(Blad1.A1:Blad3.G12) geeft 3 terug als Blad1, Blad2 en Blad3 in de opgegeven reeks bestaan.

## DDE

Geeft het resultaat van een DDE-gebaseerde koppeling. Als de inhoud van gekoppelde bereiken of secties verandert, verandert de geretourneerde waarde ook. U moet het werkblad opnieuw laden of Bewerken - Koppelingen kiezen om de bijgewerkte koppelingen te zien. Platform-onafhankelijke koppelingen zijn niet toegestaan, zoals een koppeling tussen een LibreOffice-installatie die op een Windows-machine wordt uitgevoerd, en een document dat op een Linux-machine gemaakt is.

#### Syntaxis

DDE(Server; Onderwerp/bestand; Item/bereik ; Modus (optioneel))

Server is de naam van een server-toepassing. LibreOfficetoepassingen hebben de servernaam "soffice".

Onderwerp/bestand is de volledige bestandsnaam, inclusief specificatie van het pad.

Item/bereik is het gebied met de gegevens die geëvalueerd moeten worden.

Modus is een optionele parameter die bepaalt volgens welke methode de DDE-server zijn gegevens naar getallen converteert.

Modus | Effect
--- | ---
0 of ontbreekt | Getalopmaak van het celopmaakprofiel Standaard
1 | Gegevens worden altijd in de standaardindeling voor Amerikaans Engels geïnterpreteerd.
2 | Gegevens worden als tekst opgehaald; geen conversie naar getallen

#### Voorbeeld

=DDE("soffice";"c:\office\document\data1.sxc";"blad1.A1") leest de inhoud van cel A1 in blad1 van het LibreOffice Calc-werkblad data1.sxc.

=DDE("soffice";"c:\office\document\motto.odt";"Motto van vandaag") geeft een motto terug in de cel die deze formule bevat. Eerst moet u een regel invoeren in het document motto.odt dat de tekst van het motto bevat en het definiëren als de eerste regel van een sectie genaamd Motto van vandaag (in LibreOffice Writer onder Invoegen - Sectie). Als het motto is aangepast (en opgeslagen) in het LibreOffice Writer-document wordt het motto bijgewerkt in alle cellen van LibreOffice Calc waarin deze DDE-koppeling is gedefinieerd.

## DRAAITABEL.OPHALEN

De functie DRAAITABEL.OPHALEN geeft een resultaatwaarde uit een draaitabel weer. De waarde wordt geadresseerd met behulp van veld- en itemnamen, zodat die geldig blijft als de opmaak van de draaitabel verandert.

#### Syntaxis

Twee verschillende definities van syntaxis kunnen worden gebruikt:

DRAAITABEL.OPHALEN(Gegevensveld; Draaitabel; Veldnaam / item 1 (optioneel); Veldnaam / item 2 (optioneel);) …)

of

DRAAITABEL.OPHALEN(Draaitabel; Beperkingen)

De tweede syntaxis wordt aangenomen als exact twee parameters worden opgegeven, waarvan de eerste parameter een verwijzing naar een cel of celbereik is. In alle andere gevallen wordt van de eerste syntaxis uitgegaan. De Functie-Assistent toont de eerste syntaxis.

### Eerste syntaxis

Gegevensveld is een tekenreeks die één van de gegevensvelden van de draaitabel selecteert. De tekenreeks kan de naam van de bronkolom of de naam van het gegevensveld zijn zoals weergegeven in de tabel (zoals "Som - Verkopen").

Draaitabel is een verwijzing naar een cel of celbereik dat is gepositioneerd binnen een draaitabel of een draaitabel bevat. Indien het celbereik meerdere draaitabellen bevat, wordt de tabel gebruikt die het laatst werd gemaakt.

Als er geen Veld n / Item n-paren worden opgegeven, wordt het totaal weergegeven. Anders voegt elk paar een beperking toe waaraan het resultaat moet voldoen. Veld n is de naam van een veld uit de draaitabel. Item n is de naam van een item uit dat veld.

Als de draaitabel slechts één resultaatwaarde bevat die voldoet aan alle beperkingen, of een subtotaalresultaat dat alle overeenkomende waardes samenvat, wordt dat resultaat teruggegeven. Als er geen overeenkomend resultaat, of verschillende resultaten zonder een subtotaal daarvoor is, wordt een fout teruggegeven. Deze voorwaarden zijn van toepassing op resultaten die zijn opgenomen in de draaitabel.

Als de brongegevens items bevatten die worden verborgen door de draaitabel worden zij genegeerd. De volgorde van de Veld-/Itemparen is niet belangrijk. Veld- en itemnamen zijn niet hoofdlettergevoelig.

Als er geen beperking voor een filter is opgegeven, wordt de geselecteerde waarde van het veld impliciet gebruikt. Als een beperking voor een filter wordt gegeven, moet deze overeenkomen met de geselecteerde waarde van het veld, anders wordt er een fout geretourneerd. Filters zijn de velden linksboven in een draaitabel, gevuld met behulp van het gebied "Filters" van het dialoogvenster met de draaitabelopmaak. Uit elk filter kan een item (waarde) worden geselecteerd, wat betekent dat alleen dat item in de berekening wordt meegenomen.

Subtotalen uit de draaitabel worden alleen gebruikt als zij de functie "auto" gebruiken (behalve indien gespecificeerd in de voorwaarde, zie Tweede syntaxis hieronder).

### Tweede syntaxis

Draaitabel heeft dezelfde betekenis als in de eerste syntaxis.

Beperkingen is een spatie-gescheiden lijst. Items mogen tussen aanhalingstekens staan (enkele aanhalingstekens). De gehele tekenreeks moet tussen aanhalingstekens staan (dubbele aanhalingstekens), tenzij u naar de tekenreeks verwijst vanuit een andere cel.

Eén van de ingaves kan de naam van het gegevensveld zijn. De naam van het gegevensveld kan worden weggelaten als de draaitabel slechts één gegevensveld bevat, anders moet het aanwezig zijn.

Elk van de andere ingaves specificeert een beperking in de vorm Veld[Item] (met letterlijke tekens [ en ]), of alleen Item als de itemnaam uniek is binnen alle gebruikte velden in de draaitabel.

Een functienaam kan worden toegevoegd in de vorm Veld[Item;Functie], dat er voor zorgt dat de vergelijkingsbeperking alleen het subtotaal geeft van de waardes die die functie gebruiken. De mogelijke functienamen zijn Som, Aantal, Gemiddelde, Max, Min, Product, Aantal (alleen getallen), StDev (voorbeeld), StDevP (Populatie), Var (voorbeeld) en VarP (Populatie), hoofdletterongevoelig.

## HORIZ.ZOEKEN

Zoekt naar een waarde en verwijzing naar de cellen onder het geselecteerde gebied. Deze functie verifieert of de eerste rij van een matrix een bepaalde waarde bevat. De functie geeft dan de waarde in een rij van de matrix, genoemd in de Index, in dezelfde kolom.

De zoekopdracht ondersteunt jokertekens of reguliere expressies. Als reguliere expressies zijn ingeschakeld, kunt u "all.*" invoeren, bijvoorbeeld om de eerste locatie van "all" te vinden, gevolgd door willekeurige tekens. Als u wilt zoeken naar een tekst die ook een reguliere expressie is, moet u elk metateken of operator van een reguliere expressie laten voorafgaan door een "\"-teken, of de tekst in \Q...\E insluiten. U kunt de automatische evaluatie van jokertekens of reguliere expressies in- en uitschakelen in LibreOffice - Voorkeuren Extra - Opties - LibreOffice Calc - Berekenen .

Wanneer u functies gebruikt waarbij een of meer argumenten tekenreeksen voor zoekcriteria zijn, die een reguliere expressie vertegenwoordigen, is de eerste poging om de tekenreekscriteria om te zetten naar getallen. ".0" wordt bijvoorbeeld omgezet naar 0,0 enzovoort. Als dit lukt, is de overeenkomst geen overeenkomst met een reguliere expressie, maar een numerieke overeenkomst. Als u echter overschakelt naar een landinstelling waar het decimaalteken niet de punt is, werkt de conversie van reguliere expressies. Om de uitvoering van de reguliere expressie af te dwingen in plaats van een numerieke expressie, gebruikt u een expressie die niet verkeerd kan worden gelezen als numeriek, zoals ". [0]" of ". \ 0" of "(? I) .0".

#### Syntaxis

HORIZ.ZOEKEN(Zoekcriterium; Matrix; Index ; GesorteerdBereikZoeken (optioneel))

Zie voor een uitleg van de parameters:VERT.ZOEKEN (kolommen en rijen worden gewisseld)

Afhandelen van lege cellen

#### Voorbeeld

Stel dat we een databasetabel hebben gebouwd die het celbereik A1:DO4 beslaat en basisinformatie bevat over 118 chemische elementen. De eerste kolom bevat de rijkoppen "Element", "Symbool", "Atoomnummer" en "Relatieve atomaire massa". Volgende kolommen bevatten de relevante informatie voor elk van de elementen, van links naar rechts gerangschikt op atoomnummer. De cellen B1:B4 bevatten bijvoorbeeld "waterstof", "H", "1" en "1,008", terwijl de cellen DO1:DO4 "Oganesson", "Og", "118" en "294" bevatten.

| A | B | C | D | ... | DO
--- | --- | --- | --- | --- | --- | ---
1 | Element | Waterstof | Helium | Lithium | ... | Oganesson
2 | Symbool | H | He | Li | ... | Og
3 | Atoomnummer | 1 | 2 | 3 | ... | 118
4 | Relatieve atomaire massa | 1.008 | 4.0026 | 6.94 | ... | 294

=HORIZ.ZOEKEN("Waterstof"; $A$1:$DO$4; 2; 0) geeft “H” terug, het element van waterstof.

=HORIZ.ZOEKEN("Organesson"; $A$1:$DO$4; 3; 0) geeft 118 terug, het atoomnummer van organesson.

=HORIZ.ZOEKEN("Helium"; $A$1:$DO$4; 4; 0) geeft 4.0026 terug, de relatieve atomaire massa van helium.

## HYPERLINK

Wanneer u op een cel klikt die de HYPERLINK-functie bevat, wordt de hyperlink geopend.

Als u de optionele parameter Celtekst gebruikt, zoekt de formule de URL en wordt vervolgens de tekst of het nummer weergegeven.

U opent een cel met een hyperlink als volgt via het toetsenbord: selecteer de cel, druk op F2 om de bewerkingsmodus te activeren, zet de cursor voor de hyperlink, druk op Shift+F10 en kies vervolgens Hyperlink openen.

#### Syntaxis

HYPERLINK("URL" ; Celtekst (optioneel))

URL specificeert het koppelingsdoel. De optionele parameter Celtekst is de tekst of een getal dat in de cel wordt weergegeven en als resultaat wordt geretourneerd. Als de parameter Celtekst niet is opgegeven, wordt de URL weergegeven in de celtekst en wordt deze als resultaat geretourneerd.

Het getal 0 wordt teruggegeven voor lege cellen en matrixelementen.

#### Voorbeeld

=HYPERLINK("https://nl.libreoffice.org/") geeft de tekst "https://nl.libreoffice.org/" weer in de cel en voert de hyperlink https://nl.libreoffice.org/ uit wanneer erop wordt geklikt.

=HYPERLINK("https://nl.libreoffice.org/";"Klik hier") geeft de tekst "Klik hier" weer in de cel en voert de hyperlink https://nl.libreoffice.org/ uit wanneer erop wordt geklikt.

=HYPERLINK("https://nl.libreoffice.org/";12345) geeft het getal 12345 weer en voert de hyperlink https://nl.libreoffice.org/ uit wanneer erop wordt geklikt.

=HYPERLINK($B4) waarbij cel B4 https://nl.libreoffice.org/ bevat. De functie voegt https://nl.libreoffice.org/ toe aan de URL van de hyperlinkcel en retourneert dezelfde tekst die wordt gebruikt als formuleresultaat.

=HYPERLINK("http://www.";"Klik ") & "nl.libreoffice.org/" geeft de tekst Klik voorbeeld.org weer in de cel en voert de hyperlink https://nl.libreoffice.org/ uit wanneer erop wordt geklikt.

=HYPERLINK("#Blad1.A1";"Ga naar boven") geeft de tekst Ga naar boven weer en springt naar cel Blad1.A1 in dit document als op de tekst met ingedrukte Ctrl-toets wordt geklikt.

=HYPERLINK("bestand:///C:/writer.odt#Specificatie";"Ga naar Writer-bladwijzer") geeft de tekst "Ga naar Writer-bladwijzer" weer, laadt het opgegeven tekstdocument en springt om "Specificatie" als bladwijzer te markeren.

=HYPERLINK("bestand:///C:/Documenten/";"Open documentenmap") geeft de tekst "Open documentenmap" weer en toont de mapinhoud met behulp van de standaard bestandsbeheerder in uw besturingssysteem. systeem.

De functie probeert een brug te slaan met systeemspecificaties. "c:\pad naar\bestand.ext" wordt bijvoorbeeld correct geïnterpreteerd als "bestand:///c:/pad%20naar/bestand.ext" op Windows, of ".." leidt naar de bovenliggende map van het document.

## INDEX

INDEX retourneert een verwijzing, een waarde of een reeks waardes uit een referentiebereik, gespecificeerd door rij- en kolomindexnummer of reeks rij- en reeks kolommenindexnummers, en een optionele bereikindex.

INDEX() retourneert een verwijzing als het argument een of meer verwijzingen is. Bij gebruik in een cel in de vorm =INDEX(), wordt de verwijzing opgelost en worden de waardes weergegeven. Wanneer INDEX() wordt gebruikt in argumenten van andere functies, =FUNCTIE(INDEX()...), krijgt de functie de doorgegeven referentie die is geretourneerd door INDEX(). Het retourneren van een verwijzing is anders dan het retourneren van een reeks waardes voor functies die ze anders verwerken.

#### Syntaxis

INDEX(Verwijzing ; Rij (optioneel); Kolom (optioneel); Bereik (optioneel))

Verwijzing is een verwijzing, rechtstreeks ingevoerd of door een bereiknaam op te geven. Als de verwijzing uit meerdere bereiken bestaat, moet u de lijst met verwijzingen of bereiknamen tussen haakjes plaatsen of de operator tilde (~) voor aaneenschakeling van het bereik gebruiken of definieer een benoemd bereik met meerdere gebieden.

Rij (optioneel) vertegenwoordigt de rij of de reeks rij-indexen van het referentiebereik waarvoor een waarde moet worden geretourneerd. In het geval van nul of weggelaten (geen specifieke rij) worden alle rijen waarnaar wordt verwezen geretourneerd.

Kolom (optioneel) vertegenwoordigt de kolom of matrix van kolomindexen van het referentiebereik waarvoor een waarde moet worden geretourneerd. In het geval van nul of weggelaten (geen specifieke kolom) worden alle kolommen waarnaar wordt verwezen geretourneerd.

Als Rij, Kolom of beide worden weggelaten of gedefinieerd als matrixen van indexen, moet de INDEX-functie worden ingevoerd als een>matrix-functie.

Bereik (optioneel) vertegenwoordigt de index van het subbereik als het verwijst naar een meervoudig bereik, standaard is 1.

#### Voorbeeld

{=INDEX({1;3;5;7;9;10};{2;1};1)} retourneert een matrix van 2 rijen met 7 en 1. De rij-index {2;1} kiest rij 2 en vervolgens rij 1. De kolommen index 1 kiest de eerste kolom.

{=INDEX(D3:G12;{1;2;3;4};{3;1})} retourneer een matrix van 4 rijen bij 2 kolommen. De rij-indexmatrix {1;2;3;4} kiest rijen 3 tot en met 6 en {3;1} kiest de derde (F) en eerste kolom (D). Kolommen 1 en 3 van de bronverwijzing zijn verwisseld in de resulterende matrix.

=INDEX(Prijzen;4;1) geeft de waarde uit rij 4 en kolom 1 uit het databasebereik gedefinieerd onder Gegevens - Definiëren als Prijzen.

=INDEX(SomX;4;1) geeft de waarde uit het bereik SomX in rij 4 en kolom 1 zoals gedefinieerd in Blad - Namen - Definiëren.

{=INDEX(A1:B6;1)} geeft de waardes van de eerste rij van A1:B6 terug. Voer de formule in als een matrixformule.

{=INDEX(A1:B6;0;1)} geeft de waardes van de eerste kolom van A1:B6 terug. Voer de formule in als een matrixformule.

=INDEX(A1:B6;1;1) geeft de waarde aan in de linkerbovenhoek van het bereik A1:B6.

{=INDEX((A1:B6;C1:D6);0;0;2)} geeft de waardes terug van het tweede bereik C1:D6 van het meervoudige bereik. Voer de formule in als een matrixformule.

Verwante onderwerpen

Wiki-pagina INDEX.

## INDIRECT

Geeft de verwijzing gespecificeerd door een tekenreeks. Deze functie kan ook gebruikt worden om het gebied van een overeenkomstige tekenreeks te verkrijgen.

Deze functie wordt altijd opnieuw berekend wanneer er een herberekening plaatsvindt.

Voor interoperabiliteit ondersteunen de functies ADRES en INDIRECT een optionele parameter om te specificeren of de adresnotatie R1C1 in plaats van de gebruikelijke notatie A1 moet worden gebruikt.

In ADRES wordt de parameter ingevoegd als de vierde parameter, waarbij de optionele parameter voor de bladnaam wordt verschoven naar de vijfde positie.

In INDIRECT wordt de parameter toegevoegd als de tweede parameter.

In beide functies wordt, als de instructie wordt ingevoegd met de waarde 0, de notatie R1C1 gebruikt. Als de instructie niet wordt opgegeven of een andere waarde dan 0 heeft, dan wordt de notatie A1 gebruikt.

In de notatie R1C1 geeft ADRES adressen als tekenreeksen terug met behulp van het uitroepteken '!' als het scheidingsteken voor de bladnaam en INDIRECT verwacht het uitroepteken als scheidingsteken voor de bladnaam. Beide functies gebruiken nog steeds de punt '.' als scheidingsteken voor de bladnaam met de notatie A1.

Bij het openen van documenten in de indeling ODF 1.0/1.1 zullen de ADRES-functies die een bladnaam als vierde parameter weergeven die bladnaam opschuiven om de vijfde parameter te worden. Een nieuwe vierde parameter met de waarde 1 zal worden ingevoegd.

Als ADRES-functies een vierde parameter hebben, zal die parameter worden verwijderd bij het opslaan in de indeling ODF 1.0/1.1.

Sla een werkblad niet op in de oude indeling ODF 1.0/1.1 als de nieuwe vierde parameter van de functie ADRES werd gebruikt met een waarde van 0.

De functie INDIRECT wordt opgeslagen zonder conversie naar de indeling ODF 1.0/1.1. Indien de tweede parameter aanwezig was, zal een oudere versie van Calc een fout voor die functie teruggeven.

#### Syntaxis

INDIRECT(Verwijzing ; A1 (optioneel))

Verwijzing vertegenwoordigt een verwijzing naar een cel of een gebied (in tekstvorm) waarvoor de inhoud moet worden teruggegeven.

A1 (optioneel) - indien ingesteld op 0 wordt de notatie R1C1 gebruikt. Als de parameter niet wordt opgegeven of een andere waarde dan 0 heeft, dan wordt de notatie A1 gebruikt.

Als u een Excel-werkblad opent waarin indirecte adressen gebruikt worden die berekend zijn uit tekenreeksfuncties, worden de bladadressen niet automatisch vertaald. Zo wordt het Excel-adres in INDIRECT("[filename]sheetname!"&B1) niet naar het Calc-adres in INDIRECT("filename#sheetname."&B1) geconverteerd.

#### Voorbeeld

=INDIRECT(A1) is gelijk aan 100 als A1 C108 als een verwijzing bevat en cel C108 de waarde 100 bevat.

=SOM(INDIRECT("a1:" & ADRES(1;3))) totaliseert de cellen in het gebied van A1 tot en met de cel met het adres dat gedefinieerd wordt door rij 1 en kolom 3. Dit betekent dat het gebied A1:C1 wordt getotaliseerd.

Verwante onderwerpen

wikipagina INDIRECT.

## KIEZEN

Gebruikt een index om een waarde uit een lijst met tot 30 waardes te geven.

#### Syntaxis

KIEZEN(Index; Waarde 1 ; Waarde 2 (optioneel); ...)

Index is een verwijzing of getal tussen 1 en 30 waarmee aangegeven wordt welke waarde uit de lijst genomen moet worden.

Waarde 1, Waarde 2, ..., Waarde 30 is de lijst met waardes die is ingevoerd als een verwijzing naar een cel of als individuele waardes.

#### Voorbeeld

=KIEZEN(A1;B1;B2;B3;"Vandaag";"Gisteren";"Morgen") geeft, bijvoorbeeld, de inhoud van cel B2 als A1 = 2; als A1 = 4 geeft de functie de tekst "Vandaag" terug.

## KOLOM

Retourneert het kolomnummer van een celverwijzing. Als de verwijzing een cel is, wordt het kolomnummer van de cel geretourneerd; als de parameter een celgebied is, worden de corresponderende kolomnummers geretourneerd in een enkele rij matrix als de formule wordt ingevoerd als een matrixformule. Als de functie KOLOM met een gebiedsverwijzingsparameter niet wordt gebruikt voor een matrixformule, wordt alleen het kolomnummer van de eerste cel binnen het gebied bepaald.

#### Syntaxis

KOLOM([Verwijzing])

Verwijzing is de verwijzing naar een cel of celgebied waarvan het eerste kolomnummer gevonden moet worden.

Als er geen verwijzing is ingevoerd, wordt het kolomnummer gevonden van de cel waarin de formule is ingevoerd. LibreOffice Calc stelt automatisch de verwijzing naar de huidige cel in.

#### Voorbeeld

=KOLOM(A1) is gelijk aan 1. Kolom A is de eerste kolom in de tabel.

=KOLOM(C3:E3) is gelijk aan 3. Kolom C is de derde kolom in de tabel.

=KOLOM(D3:G10) geeft 4 terug omdat kolom D de vierde kolom is in de tabel en de functie KOLOM niet wordt gebruikt als een matrixformule. (In dit geval wordt de eerste waarde van de matrix altijd gebruikt als het resultaat.)

{=KOLOMMEN(B2:B7)} en =KOLOM(B2:B7) geven beide 2 terug omdat de verwijzing alleen kolom B bevat als de tweede kolom in de tabel. Omdat gebieden met één kolom slechts één kolomnummer hebben maakt het geen verschil of de formule wordt gebruikt als matrixformule of niet.

=KOLOM() geeft 3 terug als de formule werd ingevoerd in kolom C.

{=KOLOM(Konijn)} geeft de één-kolom matrix (3, 4) terug als "Konijn" het benoemde gebied is (C1:D3).

## KOLOMMEN

Geeft het aantal kolommen in de opgegeven verwijzing.

#### Syntaxis

KOLOMMEN(Matrix)

Matrix is de verwijzing naar een celbereik waarvan het totale aantal kolommen moet worden gevonden. Het argument kan ook een enkele cel zijn.

#### Voorbeeld

=KOLOMMEN(B5) geeft 1 terug omdat een cel slechts één kolom kan bevatten.

=KOLOMMEN(A1:C5) is gelijk aan 3. De verwijzing bestaat uit drie kolommen.

=KOLOMMEN(Konijn) geeft 2 terug als Konijn het benoemde gebied is (C1:D3).

## RIJ

Retourneert het rijnummer van een celverwijzing. Als de verwijzing een cel is, wordt het rijnummer van de cel geretourneerd. Als de verwijzing een celbereik is, worden de bijbehorende rijnummers geretourneerd in een matrix met één kolom als de formule wordt ingevoerd als een matrixformule. Als de RIJ-functie met een bereikverwijzing niet wordt gebruikt in een matrixformule, wordt alleen het rijnummer van de eerste bereikcel geretourneerd.

#### Syntaxis

RIJ([Verwijzing])

Verwijzing is een cel, een gebied of de naam van een gebied.

Als u geen verwijzing opgeeft, wordt het rijnummer van de cel waarin de formule is ingevoerd, gevonden. LibreOffice Calc stelt de verwijzing naar de huidige cel automatisch in.

#### Voorbeeld

=RIJ(B3) geeft 3 terug omdat de verwijzing wijst naar de derde rij in de tabel.

{=RIJ(D5:D8)} geeft de éénkoloms-matrix (5, 6, 7, 8) terug omdat de gespecificeerde verwijzing de rijen 5 tot en met 8 bevat.

=RIJ(D5:D8) geeft 5 terug omdat de functie RIJ niet is gebruikt als matrixformule en alleen het nummer van de eerste rij van de verwijzing wordt teruggegeven.

{=RIJ(A1:E1)} en =RIJ(A1:E1) geven beide 1 terug omdat de verwijzing slechts 1 rij kan bevatten als de eerste kolom in de tabel. (Omdat gebieden met één rij slechts één rijnummer hebben maakt het geen verschil of de formule wordt gebruikt als matrixformule of niet.)

=RIJ() geeft 3 terug als de formule werd ingevoerd in rij 3.

{=RIJ(Konijn)} geeft de één-kolom matrix (3, 4) terug als "Konijn" het benoemde gebied is (C1:D3).

## RIJEN

Geeft als resultaat het aantal rijen in een verwijzing of matrix.

#### Syntaxis

RIJEN(Matrix)

Matrix is de verwijzing of het benoemde gebied waarvan het totale aantal rijen moet worden bepaald.

#### Voorbeeld

=RIJEN(B5) geeft 1 terug omdat een cel slechts één rij bevat.

=RIJEN(A10:B12) geeft 3 terug.

=RIJEN(Konijn) geeft 3 terug als "Konijn" het benoemde gebied is (C1:D3).

## TYPEFOUT

Geeft het getal dat overeenkomt met een foutwaarde in een andere cel. Met behulp van dit getal kunt u de tekst van een foutmelding genereren.

Als er een fout optreedt, wordt met de functie een logische of numerieke waarde als resultaat gegeven.

De statusbalk geeft de vooraf gedefinieerde foutcode van LibreOffice weer, als u op de cel met de fout klikt.

#### Syntaxis

TYPEFOUT(Verwijzing)

Verwijzing bevat het adres van de cel waarin de fout optreedt.

#### Voorbeeld

De functie =TYPEFOUT(A1) geeft het getal 518 terug als cel A1 toont Fout:518.

#### Technische informatie

Deze functie maakt geen deel uit van de Open Document Format for Office Applications (OpenDocument) Versie 1.3. Deel 4: Herberekende formule (OpenFormula) indeling standaard. De naamafstand is

ORG.OPENOFFICE.ERRORTYPE

## VERGELIJKEN

Geeft de relatieve positie in een matrix van een item dat met een gespecificeerde waarde overeenkomt. De functie geeft de positie van de gevonden waarde in de zoekmatrix als een getal.

#### Syntaxis

VERGELIJKEN(Zoekcriterium; Zoekmatrix ; Type (optioneel))

Zoekcriterium is de waarde waarnaar moet worden gezocht in de matrix met één rij of één kolom.

Zoekmatrix is de doorzochte verwijzing. Een zoekmatrix kan een enkele rij of kolom zijn, of deel van een enkele rij of kolom.

Type kan de waardes 1, 0 of -1 hebben. Als Type = 1 of als deze optionele parameter ontbreekt, wordt aangenomen dat de eerste kolom van de zoekmatrix oplopend is gesorteerd. Als Type = -1 wordt ervan uitgegaan dat de kolom aflopend gesorteerd is. Dit komt overeen met dezelfde functie in Microsoft Excel.

Als Type = 0 worden alleen exacte overeenkomsten gevonden. Als het zoekcriterium meer dan één keer wordt gevonden, geeft de functie de index van de eerste overeenkomende waarde. Alleen als Type = 0 kunt u zoeken met reguliere uitdrukkingen (als dit in de rekenopties is aangezet) of jokertekens (als dit in de rekenopties is aangezet).

Als Type = 1 of de derde parameter ontbreekt, wordt de index van de laatste waarde die kleiner is dan of gelijk is aan het zoekcriterium geretourneerd. Voor Type = -1 wordt de index van de laatste waarde die groter of gelijk is geretourneerd.

De zoekopdracht ondersteunt jokertekens of reguliere expressies. Als reguliere expressies zijn ingeschakeld, kunt u "all.*" invoeren, bijvoorbeeld om de eerste locatie van "all" te vinden, gevolgd door willekeurige tekens. Als u wilt zoeken naar een tekst die ook een reguliere expressie is, moet u elk metateken of operator van een reguliere expressie laten voorafgaan door een "\"-teken, of de tekst in \Q...\E insluiten. U kunt de automatische evaluatie van jokertekens of reguliere expressies in- en uitschakelen in LibreOffice - Voorkeuren Extra - Opties - LibreOffice Calc - Berekenen .

Wanneer u functies gebruikt waarbij een of meer argumenten tekenreeksen voor zoekcriteria zijn, die een reguliere expressie vertegenwoordigen, is de eerste poging om de tekenreekscriteria om te zetten naar getallen. ".0" wordt bijvoorbeeld omgezet naar 0,0 enzovoort. Als dit lukt, is de overeenkomst geen overeenkomst met een reguliere expressie, maar een numerieke overeenkomst. Als u echter overschakelt naar een landinstelling waar het decimaalteken niet de punt is, werkt de conversie van reguliere expressies. Om de uitvoering van de reguliere expressie af te dwingen in plaats van een numerieke expressie, gebruikt u een expressie die niet verkeerd kan worden gelezen als numeriek, zoals ". [0]" of ". \ 0" of "(? I) .0".

#### Voorbeeld

=VERGELIJKEN(200;D1:D100) doorzoekt het gebied D1:D100, dat is gesorteerd op kolom D, naar de waarde 200. Zodra deze waarde wordt bereikt, wordt het rijnummer waarin die werd gevonden teruggegeven. Indien een hogere waarde werd gevonden tijdens het doorzoeken van de kolom, wordt het nummer van de vorige rij teruggegeven.

## VERSCHUIVING

Geeft de waarde van een celverschuiving met een bepaald aantal rijen en kolommen vanaf een bepaald referentiepunt.

Deze functie wordt altijd opnieuw berekend wanneer er een herberekening plaatsvindt.

#### Syntaxis

VERSCHUIVING(Verwijzing; Rijen; Kolommen ; Hoogte (optioneel); Breedte (optioneel))

Verwijzing is de verwijzing van waaruit de functie zoekt naar de nieuwe verwijzing.

Rijen is het aantal rijen waarmee de verwijzing werd gecorrigeerd naar boven (negatieve waarde) of naar beneden.

Kolommen is het aantal kolommen waarmee de verwijzing werd gecorrigeerd naar links (negatieve waarde) of naar rechts. Gebruik 0 om in dezelfde kolom te blijven.

Hoogte (optioneel) is de verticale hoogte voor een gebied dat begint op de positie van de nieuwe verwijzing.

Breedte (optioneel) is de horizontale breedte voor een gebied dat begint op de positie van de nieuwe verwijzing.

Argumenten Rijen en Kolommen mogen niet leiden tot nul of een negatieve startrij of -kolom.

Argumenten Hoogte en Breedte mogen niet leiden tot nul of een negatief aantal rijen of kolommen

In de functies van LibreOffice Calc kunnen "optionele" parameters alleen weggelaten worden wanneer er geen parameter volgt. In een functie met vier parameters waarvan de laatste twee als "optioneel" gemarkeerd zijn, kunt u bijvoorbeeld parameter 4 of parameter 3 en 4 weglaten, maar niet alleen parameter 3.

#### Voorbeeld

=VERSCHUIVING(A1;2;2) geeft de waarde in cel C3 terug (A1 twee rijen en twee kolommen naar beneden verplaatst). Als C3 de waarde 100 bevat geeft deze functie de waarde 100 terug.

=VERSCHUIVING(B2:C3;1;1) geeft een verwijzing naar B2:C3 terug, 1 rij naar beneden en één kolom naar rechts verplaatst (C3:D4).

=VERSCHUIVING(B2:C3;-1;-1) geeft een verwijzing naar B2:C3 terug, 1 rij naar boven en één kolom naar links verplaatst (A1:B2).

=VERSCHUIVING(B2:C3;0;0;3;4) geeft een verwijzing naar B2:C3 terug, herschaald naar 3 rijen en 4 kolommen (B2:E4).

=VERSCHUIVING(B2:C3;1;0;3;4) geeft een verwijzing naar B2:C3 terug, 1 rij naar beneden verplaatst en opnieuw geschaald naar 3 rijen en 4 kolommen (B2:E4).

=SOM(VERSCHUIVING(A1;2;2;5;6)) bepaalt het totaal van het gebied dat begint in cel C3 en een hoogte heeft van 5 rijen en een breedte van 6 kolommen (gebied=C3:H7).

Als Breedte of Hoogte is opgegeven, retourneert de functie OFFSET een celbereikverwijzing. Als Verwijzing een enkele celverwijzing is en zowel Breedte en Hoogte zijn weggelaten, wordt een enkele celverwijzing geretourneerd.

## VERT.ZOEKEN

Verticaal zoeken met verwijzing naar aangrenzende cellen aan de rechterkant. Deze functie controleert of een specifieke waarde in de eerste kolom van een array staat. De functie retourneert dan de waarde in dezelfde rij van de kolom genoemd door Index. Als de parameter Gesorteerd wordt weggelaten of wordt ingesteld op WAAR of één, wordt aangenomen dat de gegevens in oplopende volgorde worden gesorteerd. In dit geval, als de exacte Lookup niet wordt gevonden, wordt de laatste waarde die kleiner is dan het criterium geretourneerd. Als Gesorteerd is ingesteld op ONWAAR of nul, moet een exacte overeenkomst worden gevonden, anders zal de fout Fout: Waarde niet beschikbaar het resultaat zijn. Met een waarde van nul hoeven de gegevens dus niet in oplopende volgorde te worden gesorteerd.

De zoekopdracht ondersteunt jokertekens of reguliere expressies. Als reguliere expressies zijn ingeschakeld, kunt u "all.*" invoeren, bijvoorbeeld om de eerste locatie van "all" te vinden, gevolgd door willekeurige tekens. Als u wilt zoeken naar een tekst die ook een reguliere expressie is, moet u elk metateken of operator van een reguliere expressie laten voorafgaan door een "\"-teken, of de tekst in \Q...\E insluiten. U kunt de automatische evaluatie van jokertekens of reguliere expressies in- en uitschakelen in LibreOffice - Voorkeuren Extra - Opties - LibreOffice Calc - Berekenen .

Wanneer u functies gebruikt waarbij een of meer argumenten tekenreeksen voor zoekcriteria zijn, die een reguliere expressie vertegenwoordigen, is de eerste poging om de tekenreekscriteria om te zetten naar getallen. ".0" wordt bijvoorbeeld omgezet naar 0,0 enzovoort. Als dit lukt, is de overeenkomst geen overeenkomst met een reguliere expressie, maar een numerieke overeenkomst. Als u echter overschakelt naar een landinstelling waar het decimaalteken niet de punt is, werkt de conversie van reguliere expressies. Om de uitvoering van de reguliere expressie af te dwingen in plaats van een numerieke expressie, gebruikt u een expressie die niet verkeerd kan worden gelezen als numeriek, zoals ". [0]" of ". \ 0" of "(? I) .0".

#### Syntaxis

=VERT.ZOEKEN(Zoekcriterium; Matrix; Index ; Gesorteerd bereik zoeken (optioneel))

Zoekcriterium is de waarde van elk type waarnaar wordt gezocht in de eerste kolom van de matrix.

Matrix is de referentie, die bestaat uit minstens evenveel kolommen als het aantal dat is doorgegeven in het argument Index..

Index is het getal van de kolom in de matrix dat de waarde bevat die moet worden teruggegeven. De eerste kolom heeft het getal 1.

Gesorteerd bereik zoeken is een optionele parameter die aangeeft of de eerste kolom in de matrix bereikgrenzen bevat in plaats van gewone waarden. In deze modus retourneert het Zoekcriterium de waarde in de rij waarbij de eerste kolom een waarde heeft die gelijk is aan of kleiner is dan Zoekcriterium. Het kan bijvoorbeeld datums bevatten waarop een bepaalde belastingwaarde is gewijzigd, en daarom vertegenwoordigen de waardes begindatums van een periode waarin een specifieke belastingwaarde van kracht was. Als u dus zoekt naar een datum die niet voorkomt in de eerste matrixkolom, maar tussen een aantal bestaande grensdatums valt, krijgt u de laagste datum, zodat u kunt achterhalen of de gegevens van kracht zijn voor de gezochte datum. Voer de Booleaanse waarde ONWAAR of nul in als de eerste kolom geen lijst met bereikgrenzen is. Als deze parameter WAAR is of niet gegeven, moet de eerste kolom in de matrix in oplopende volgorde worden gesorteerd. Gesorteerde kolommen kunnen veel sneller worden doorzocht en de functie retourneert altijd een waarde, zelfs als de zoekwaarde niet exact overeenkomt, als deze groter is dan de laagste waarde van de gesorteerde lijst. In ongesorteerde lijsten moet de zoekwaarde exact overeenkomen. Anders retourneert de functie #N/B met het bericht: Fout: Waarde niet beschikbaar.

Afhandelen van lege cellen

#### Voorbeeld

U wilt het nummer van een gerecht in het menu in cel A1 invoeren en de naam van het gerecht moet onmiddellijk als tekst verschijnen in de naastgelegen cel (B1). De toewijzing Nummer aan Naam is opgenomen in de matrix D1:E100. D1 bevat 100, E1 bevat de naam Groentensoep enzovoort, voor 100 menu-items. De getallen in kolom D zijn oplopend gesorteerd; dus, de optionele parameter Sorteren is niet nodig.

Voer de volgende formule in B1 in:

=VERT.ZOEKEN(A1;D1:E100;2)

Zodra u een getal in A1 invoert, verschijnt in B1 de overeenkomstige tekst die in de tweede kolom van verwijzing D1:E100 staat. Wanneer u een niet-bestaand getal invoert, wordt de tekst bij het volgende getal naar beneden weergegeven. U kunt dit voorkomen door ONWAAR in te voeren als laatste parameter in de formule, zodat er een foutmelding wordt gegenereerd wanneer er een niet-bestaand getal wordt ingevoerd.

## ZOEKEN

Geeft de inhoud van een cel weer of uit een één-rij of één-kolom bereik. Optioneel wordt de toegewezen waarde (van dezelfde index) teruggegeven in een andere kolom en rij. Tegengesteld aan VERT.ZOEKEN en HORIZ.ZOEKEN mogen de zoek- en resultaatvector op verschillende posities liggen; zij hoeven niet aanliggend te zijn. Aansluitend daarop moet de zoekvector voor OPZOEKEN oplopend gesorteerd zijn, anders zal de zoekactie geen bruikbare resultaten teruggeven.

Als OPZOEKEN het zoekcriterium niet kan vinden, retourneert de functie de grootste waarde in de zoekvector die minder is dan of gelijk is aan het zoekcriterium.

De zoekopdracht ondersteunt jokertekens of reguliere expressies. Als reguliere expressies zijn ingeschakeld, kunt u "all.*" invoeren, bijvoorbeeld om de eerste locatie van "all" te vinden, gevolgd door willekeurige tekens. Als u wilt zoeken naar een tekst die ook een reguliere expressie is, moet u elk metateken of operator van een reguliere expressie laten voorafgaan door een "\"-teken, of de tekst in \Q...\E insluiten. U kunt de automatische evaluatie van jokertekens of reguliere expressies in- en uitschakelen in LibreOffice - Voorkeuren Extra - Opties - LibreOffice Calc - Berekenen .

Wanneer u functies gebruikt waarbij een of meer argumenten tekenreeksen voor zoekcriteria zijn, die een reguliere expressie vertegenwoordigen, is de eerste poging om de tekenreekscriteria om te zetten naar getallen. ".0" wordt bijvoorbeeld omgezet naar 0,0 enzovoort. Als dit lukt, is de overeenkomst geen overeenkomst met een reguliere expressie, maar een numerieke overeenkomst. Als u echter overschakelt naar een landinstelling waar het decimaalteken niet de punt is, werkt de conversie van reguliere expressies. Om de uitvoering van de reguliere expressie af te dwingen in plaats van een numerieke expressie, gebruikt u een expressie die niet verkeerd kan worden gelezen als numeriek, zoals ". [0]" of ". \ 0" of "(? I) .0".

#### Syntaxis

ZOEKEN(Zoekcriterium; Zoekvector ; Resultaatvector (optioneel))

Zoekcriterium is de waarde van elk type waarnaar moet worden gezocht; direct of als referentie ingevoerd.

Zoekvector is het gebied van één rij of één kolom dat moet worden doorzocht.

Resultaatvector is een ander één-rij of één-kolom bereik van waaruit het resultaat van de functie wordt genomen. Het resultaat is de cel van de resultaatvector met dezelfde index als het gevonden item in de zoekvector.

Afhandelen van lege cellen

#### Voorbeeld

=ZOEKEN(A1;D1:D100;F1:F100) zoekt naar de corresponderende cel in het bereik D1:D100 voor het getal dat u heeft ingevoerd in A1. Voor het gevonden item wordt de index bepaald, bijvoorbeeld de 12e cel in dit bereik. Dan wordt de inhoud van de 12e cel teruggeven als de waarde van de functie (in de resultaatvector).

Verwante onderwerpen

Functies per categorie